A reader recently sent me a note saying he was trying to add CAPTCHA to his site. He had been trying to see how I used it in BlogCFC, and was just confused by what he saw. I thought I'd write a quick and simple guide for getting CAPTCHA on a form.

First - let's look at a simple form without CAPTCHA.
   view plainprintabout
1  <cfparam name="form.name" default="">
2  <cfparam name="form.email" default="">
3  <cfparam name="form.comments" default="">
4  <cfset showForm = true>
5  
6  <cfif structKeyExists(form, "sendcomments")>
7      <cfset error = "">
8      <cfif not len(trim(form.name))>
9          <cfset error = error & "You must include your name, bozo.<br>">
10      </cfif>
11      <cfif not len(trim(form.email)) or not isValid("email", form.email)>
12          <cfset error = error & "Include a valid email address idiot!<br>">
13      </cfif>
14      <cfif not len(trim(form.comments))>
15          <cfset error = error & "It's called a Comment Form, stupid.<br>">
16      </cfif>
17      <cfif error is "">
18          <cfmail to="foo@foo.com" from="#form.email#" subject="Pointless comments from the public" wraptext="75">
19  From: #form.name# (#form.email#)
20  Comments:
21  #form.comments#
22          </cfmail>
23          <cfset showForm = false>
24      </cfif>
25  </cfif>
26      
27  <cfif showForm>
28      <cfif structKeyExists(variables, "error")>
29          <cfoutput>
30          <p>
31          <b>Please correct these errors:<br>
32          #error#
33          </b>
34          </p>
35          </cfoutput>
36      </cfif>
37      
38      <cfoutput>
39      <form action="test.cfm" method="post">
40      <table>
41          <tr>
42              <td>Your Name:</td>
43              <td><input type="text" name="name" value="#form.name#"></td>
44          </tr>
45          <tr>
46              <td>Your Email:</td>
47              <td><input type="text" name="email" value="#form.email#"></td>
48          </tr>
49          <tr>
50              <td>Your Comments:</td>
51              <td><textarea name="comments">#form.comments#</textarea></td>
52          </tr>
53          <tr>
54              <td> </td>
55              <td><input type="submit" name="sendcomments" value="Send Comments"></td>
56          </tr>
57      </table>
58      </form>
59      </cfoutput>
60  <cfelse>
61      <cfoutput>
62      <p>
63      Thank you for sending your comments, #form.name#.
64      </p>
65      </cfoutput>
66  </cfif>
I'm not going to say anything about this code as it's a fairly typical form. This will serve as a base form that we will be adding CAPTCHA too. There are multiple CAPTCHA solutions out there, including the built-in support in BlueDragon and Alagad's CAPTCHA component. For this demo however I'm going to use the same product I used in BlogCFC, Lyla Captcha. This is a free product and is pretty simple to get up and running quickly. Download the product and unzip it to a folder. Any folder will do. Just make sure your application can access it. The first thing we will do in our new form is to create an instance of the CFC:
   view plainprintabout
1  <cfif not structKeyExists(application, "captcha")>
2      <cfset application.captcha = createObject("component", "captchaService").init(configFile="captcha.xml") />
3      <cfset application.captcha.setup()>
4  </cfif>
Lyla Captcha is configured via an XML file. You don't need to touch it immediately though. (Although I'll be pointing to a darn good blog entry about this XML file later on.) Now we need to add the CAPTCHA to the form. I added a new row to my table with this code:
   view plainprintabout
1  <tr>
2      <td>Enter Text Shown in Picture:</td>
3      <td>
4      <input type="text" name="captcha"><br>
5      <!--- Captcha --->
6      <cfset captcha = application.captcha.createHashReference()>
7      <img src="captcha.cfm?hash=#captcha.hash#">
8      <input name="hash" type="hidden" value="#captcha.hash#" />
9      </td>
10  </tr>
There are a few things going on here. First off - I added a new text field so the user can type in the CAPTCHA text. I then ask Lyla to create a hash reference. This is a long, random string. I pass this to a CFM that will serve up an image. Lastly, I add the hash itself as a hidden form field. Let's leave our form for a second and look at captcha.cfm:
   view plainprintabout
1  <cfif not structKeyExists(url, "hash")>
2      <cfabort>
3  </cfif>
4  
5  <cfset variables.captcha = application.captcha.createCaptchaFromHashReference("stream",url.hash) />
6  <cfcontent type="image/jpg" variable="#variables.captcha.stream#" reset="false" />
I do a quick check to ensure the url variable exists, and then I simply use the Lyla Captcha built in functions to get the image data. (You can also store the CAPTCHA as a physical file.) Now let's return back to the form. To validate the CAPTCHA, I simply call one more function in the CFC:
   view plainprintabout
1  <cfif not application.captcha.validateCaptcha(form.hash, form.captcha)>
2      <cfset error = error & "You did not match the image text. Try again with half a brain.<br>">
3  </cfif>
That's it! Lyla is pretty trivial to use and you can't beat the price. Charlie Arehart also has a blog article on how to simplify the CAPTCHA text a bit - and I definitely recommend following his suggestions: Simplifying the captcha graphic in Lyla Captcha (and BlogCFC) I've included all of my text files in the attachment to this blog entry. test.cfm is the original file and test2.cfm is the file with flareCAPTCHA.