I'm definitely not the first person to do this - but I've been itching to do drop shadows ever since I started playing with ColdFusion 8's new image functionality. My UDF is rather simple. It takes an image and duplicates it. It fills the canvas with white - and than adds an offset black square the same size as the original image. It does a blur, and then pastes on the original image. That by itself isn't too interesting, but what was interesting is why I had to duplicate the original image. When I first wrote the code, I simply used imageNew. However, whenever I tried to imageOverlay the original image onto the new one, I got:

Overlay operation requires the two sources to match in number of bands and data type.

Stumped - I dumped imageInfo on both. I wasn't sure what bands meant - but colormode_type on my original image was "ComponentColorModel" ,and the value in my new image made from scratch was "PackedColorModel". That made as much sense to me as arithmetic would make to Paris Hilton. So for the heck of it, I just tried imageNew using ARGB. I figured grayscale wouldn't work. Using ARGB didn't help at all. So does anyone know how you would make an image from scratch that would work with a (as far as I know) average JPG? The code is pasted at the very bottom. Let me show some examples of the output. First the original image.


Writing PHP is hard!

Now to make the drop shadow:
   view plainprintabout
1  <cfset myimage=makeShadow("sadgirl.jpg",5,5)>
2  <cfimage action="writeToBrowser" source="#myimage#">


.Net makes Mommy and Daddy fight.

And finally an example with what I call the blood red shadow:
   view plainprintabout
1  <cfset myimage=makeShadow("sadgirl.jpg",5,5, "90,0,0")>
2  <cfimage action="writeToBrowser" source="#myimage#">


Rails broke all my toys and Ruby killed my dog!

And finally - the UDF. Enjoy:
   view plainprintabout
1  <cffunction name="makeShadow" returnType="any" output="false">
2      <cfargument name="image" type="any" required="true">
3      <cfargument name="offset" type="numeric" required="true">
4      <cfargument name="blur" type="numeric" required="true">
5      <cfargument name="shadowcol" type="string" required="false" default="145,145,145">
6      <cfargument name="backgroundcol" type="string" required="false" default="white">
7      
8      <cfset var newwidth = "">
9      <cfset var newheight = "">
10      <cfset var shadow = "">
11      
12      <!--- if not image, assume path --->
13      <cfif not isImage(arguments.image) and not isImageFile(arguments.image)>
14          <cfthrow message="The value passed to makeShadow was not an image.">
15      </cfif>
16      
17      <cfif isImageFile(arguments.image)>
18          <cfset arguments.image = imageRead(arguments.image)>
19      </cfif>
20  
21      <cfset newwidth = arguments.image.width + (2*offset)>
22      <cfset newheight = arguments.image.height + (2*offset)>
23  
24      <!--- make a black image the same size as orig --->
25      <cfset shadow = duplicate(arguments.image)>
26      <cfset imageResize(shadow, newwidth, newheight)>
27      <cfset imageSetDrawingColor(shadow,arguments.backgroundcol)>
28      <cfset imageDrawRect(shadow, 0, 0, newwidth, newheight, true)>
29      <cfset imageSetDrawingColor(shadow,arguments.shadowcol)>
30      <cfset imageDrawRect(shadow, arguments.offset, arguments.offset, arguments.image.width, arguments.image.height, true)>
31      
32      <cfset imageBlur(shadow, arguments.blur)>
33      
34      <!--- copy orig --->
35      <cfset imagePaste(shadow,arguments.image,0,0)>
36      
37      <cfreturn shadow>
38  </cffunction>