All major database products have tools to let you backup their databases. MySQL makes it super simple with their command line tools. But what if you want to do it with ColdFusion? Doesn't everyone want to do everything with ColdFusion? I know I do! So let's look at a quick example.

My database backup code will work like so:
  1. Get a list of tables from a datasource.
  2. Select all rows from the table.
  3. Convert the query into WDDX.
  4. Zip the giant XML string and store the result.
The code for all this is incredibly simple:
   view plainprintabout
1  <cfset datasource="blogdev">
2  
3  <cfdbinfo datasource="#datasource#" name="tables" type="tables">
This code simply uses the new cfdbinfo tag to query the tables from the datasource.
   view plainprintabout
1  <!--- One struct to rule them all... --->
2  <cfset data = structNew()>
I'm going to store all my queries in one struct.
   view plainprintabout
1  <cfloop query="tables">
2      <!--- grab all data from table --->
3      <cfquery name="getData" datasource="#datasource#">
4      select    *
5      from    #table_name#
6      </cfquery>
7      
8      <cfset data[table_name] = getData>
9  </cfloop>
Then I loop over each table and select *. Notice I store the query into the struct. By the way - the cfdbinfo tag also lets you get the columns from a database table. But since this is a "quickie" script, I don't mind using the select *.
   view plainprintabout
1  <!--- Now serialize into one ginormous string --->
2  <cfwddx action="cfml2wddx" input="#data#" output="packet">
Then we convert the structure into one XML packet.
   view plainprintabout
1  <!--- file to store zip --->
2  <cfset zfile = expandPath("./data.zip")>
3  
4  <!--- Now zip this baby up --->
5  <cfzip action="zip" file="#zfile#" overwrite="true">
6      <cfzipparam content="#packet#" entrypath="data.packet">
7  </cfzip>
Next I store the string into a zip using the new cfzip and cfzipparam tags. Notice how I feed the string data to the zip using cfzipparam. I don't have to store the text into a temporary file.
   view plainprintabout
1  <cfoutput>
2  I retrieved #tables.recordCount# tables from datasource #datasource# and saved it to #zfile#.
3  </cfoutput>
The last thing I do is output a simple result message so you know how much data was backed up. Here is the complete source in one listing:
   view plainprintabout
1  <cfset datasource="blogdev">
2  
3  <cfdbinfo datasource="#datasource#" name="tables" type="tables">
4  
5  <!--- One struct to rule them all... --->
6  <cfset data = structNew()>
7  
8  <cfloop query="tables">
9      <!--- grab all data from table --->
10      <cfquery name="getData" datasource="#datasource#">
11      select    *
12      from    #table_name#
13      </cfquery>
14      
15      <cfset data[table_name] = getData>
16  </cfloop>
17  
18  <!--- Now serialize into one ginormous string --->
19  <cfwddx action="cfml2wddx" input="#data#" output="packet">
20  
21  <!--- file to store zip --->
22  <cfset zfile = expandPath("./data.zip")>
23  
24  <!--- Now zip this baby up --->
25  <cfzip action="zip" file="#zfile#" overwrite="true">
26      <cfzipparam content="#packet#" entrypath="data.packet">
27  </cfzip>
28  
29  <cfoutput>
30  I retrieved #tables.recordCount# tables from datasource #datasource# and saved it to #zfile#.
31  </cfoutput>