A few days ago I saw on Twitter a request for code that would convert roman numerals to decimal. CFLib has a UDF for going from decimal to Roman, but not the other way. I did a bit of searching and while I found a bunch of code libraries, I didn't find one that explained the logic behind the translation. Finally I came across this page: Roman Numerals, which I thought explained the issue very nicely. The basic process to convert from Roman to decimal is:

1) Read the numbers from left to right.
2) Each number is added to the next...
3) Except when the next number is larger than the current number. Then you take the pair and do a subtraction.

So with this logic in mind, I came up with the following UDF. It assumes valid Roman numerals for input. But it seems to work ok.

   view plainprintabout
1  function romantodec(input) {
2      var romans = {};
3      var result = 0;
4      var pos = 1;
5      var char = "";
6      var thisSum = "";
7      var nextchar = "";
8          
9      romans["I"] = 1;
10      romans["V"] = 5;
11      romans["X"] = 10;
12      romans["L"] = 50;
13      romans["C"] = 100;
14      romans["D"] = 500;
15      romans["M"] = 1000;
16  
17      while(pos lte len(input)) {
18          char = mid(input, pos, 1);
19          //are we NOT at the end?
20          if(pos != len(input)) {
21              //check my next character - if bigger, replace with a sub
22              nextchar = mid(input, pos+1, 1);
23              if(romans[char] < romans[nextchar]) {
24                  thisSum = romans[nextchar] - romans[char];
25                  result += thisSum;
26                  pos+=2;
27              } else {
28                  result += romans[char];
29                  pos++;
30              }
31          } else {
32              result += romans[char];
33              pos++;
34          }
35      }
36      
37      return result;
38  }

You can see how it follows the basic, 'left to right, add the numbers together' process, and how it notices when the current character has a higher number to the right of it. I wrote up a quick test script for it like so:

   view plainprintabout
1  <cfset inputs = "XX,XI,IV,VIII,MC,DL,XL">
2  <cfloop index="input" list="#inputs#">
3      <cfoutput>
4      #input#=#romantodec(input)#<br/>
5      </cfoutput>
6  </cfloop>

Which produced:

XX=20
XI=11
IV=4
VIII=8
MC=1100
DL=550
XL=40
You can download this UDF at CFLib now: romanToDecimal p.s. Sorry for those still waiting for UDF approval at CFLib. It is a volunteer process (myself, Scott Pinkston, Todd Sharp) so be patient!